Développement .NET par Cyril

Voici donc la nouvelle version de l'utilitaire "LiveBox AutoReboot" dans sa version 2.

Vous pouvez l'installer à partir de cette page :

http://cyrilhome.over-blog.net/pages/LiveBox_AutoReboot-33442.html

Cet utilitaire permet de vérifier si la LiveBox est connectée à Internet. Il ne fonctionne qu'avec la LiveBox Sagem qui accepte les commandes Telnet au contraire du model Inventel.

Il est parfois nécessaire de récupérer le champ UserId pour, par exemple, l'insérer dans une autre table pour créer une relation.

Voici comment procéder :

Code :

' On verifie que l'utilisateur est identifié

If My.User.IsAuthenticated Then
           ' on récupère les données de l'utilisateur

            Dim mu As MembershipUser = Membership.GetUser()
            Dim key As Guid

            ' On récupère le Guid du champ UserId
            key = mu.ProviderUserKey
End If

Il est parfois nécessaire de redémarrer une application, suite  à une mise à jour ou une erreur critique par exemple. Une seule ligne suffit pour réaliser cette action :

Code :

System.Windows.Forms.Application.Restart()

Il existe biensur plusieurs façons de procéder mais j'affectionne particulièrement celle-ci.

Code :

Public ds as New Dataset

Public Sub FillDataset()

GetDatabaseSchema()
        For Each dt As DataTable In ds.Tables
            FillTable(dt)
       Next

End Sub

Public Sub GetDatabaseSchema()
        Dim dtTableName As New DataTable("Tables")

        Using con As New SqlConnection(My.Settings.dbHcProspectionConnectionString)
            Dim Command As New SqlCommand
            Command = con.CreateCommand
            Command.CommandText = "select table_name as Name from INFORMATION_SCHEMA.Tables where TABLE_TYPE ='BASE TABLE'"

            con.Open()

           'on charge dans une datatable la liste des tables de la base de donnée

            dtTableName.Load(Command.ExecuteReader(CommandBehavior.CloseConnection))

            Dim tableName As String = Nothing

       'on récupère le schema de chaque table  

        For Each row As DataRow In dtTableName.Rows
                tableName = row("Name").ToString
                Using da As New SqlDataAdapter("SELECT * FROM " & tableName, con)
                    da.FillSchema(ds, SchemaType.Source, tableName)
                End Using
            Next
            con.Close()
        End Using
End Sub

Public Sub FillTable(ByVal dt As DataTable)
        Using con As New SqlConnection(My.Settings.dbHcProspectionConnectionString)
            Using da As New SqlDataAdapter("SELECT * FROM " & dt.TableName, con)
                da.Fill(ds, dt.TableName)
            End Using
        End Using
End Sub

Il ne vous reste plus qu'à appeller la méthode FillDataset pour charger les données ou GetDatabaseSchema pour ne charger que le schema de la base de données dans le dataset.

Pour cet exemple, nous allons prendre 3 tables dans une base de données :

Table Coureurs ayant les champs suivants :

• pkCoureur (clef primaire GUID)
• nomCoureur

Table Courses ayant les champs suivants :

• pkCourse (clef primaire GUID)
• nomCourse

Table CoureursCourses ayant les champs suivants :

• pkCoureurCourse (clef primaire GUID)
• fkCourse (clef étrangère GUID)
• fkCoureur (clef étrangère GUID)

La table CoureursCourses permet de faire la relation entre les courses et les coureurs, ainsi, un coureur peut participer à plusieurs courses et une course peut être courue par plusieurs coureurs. Nous avons donc une relation de plusieurs à plusieurs.

Nous allons créer une fenêtre frmCourses dand laquelle nous allons mettre 2 DataGridView (dgvCourses et dgvCoureurs).

Voici comment procéder pour afficher les coureurs qui sont inscrit à une course :

Code :

Imports System.Data.SqlClient
Imports system.ComponentModel
Imports System.Text

Public Class frmCourses
    Private bsCourses As BindingSource
    Private bsCoureurs As BindingSource
    Private ds As DataSet

    Public Sub New()

        InitializeComponent()

       ' charger les données
        LoadData()

        ' Lier les datagridview aux bindingsources
        Me.dgvCoureurs.DataSource = bsCoureurs
        Me.dgvCourses.DataSource = bsCourses

        ' Gérer l'événement de changement de position de bsCourses
        AddHandler bsCourses.PositionChanged, AddressOf bsCourses_OnPositionChanged

    End Sub

    Private Sub frmCourses_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
       ' on filtre les coureurs au chargement
        Me.FiltrerCoureurs()
    End Sub

    Private Sub LoadData()
       ' charger les données dans le dataset
        ds = New DataSet
        Using con As New SqlConnection(My.Settings.dbCoursesConnectionString)
            Using da As New SqlDataAdapter("SELECT * FROM Courses", con)
                da.Fill(ds, "Courses")
            End Using
            Using da As New SqlDataAdapter("SELECT * FROM Coureurs", con)
                da.Fill(ds, "Coureurs")
            End Using
            Using da As New SqlDataAdapter("SELECT * FROM CoureursCourses", con)
                da.Fill(ds, "CoureursCourses")
            End Using
        End Using

        ' Créer les relations
        Dim relation As DataRelation

        relation = New DataRelation("relationCoureurs_CoureursCourses", _
                                           ds.Tables("Coureurs").Columns("pkCoureur"), _
                                           ds.Tables("CoureursCourses").Columns("fkCoureur"))
        Me.ds.Relations.Add(relation)

        relation = New DataRelation("relationCourses_CoureursCourses", _
                                                   ds.Tables("Courses").Columns("pkCourse"), _
                                                   ds.Tables("CoureursCourses").Columns("fkCourse"))
        Me.ds.Relations.Add(relation)

        ' Bind les bindingsource aux données
        bsCourses = New BindingSource
        bsCourses.DataSource = ds
        bsCourses.DataMember = "Courses"

        bsCoureurs = New BindingSource
        bsCoureurs.DataSource = ds
        bsCoureurs.DataMember = "Coureurs"

    End Sub

    Private Sub bsCourses_OnPositionChanged(ByVal sender As Object, ByVal e As System.EventArgs)
        ' Filtrer les coureurs pour la course courante
        Me.FiltrerCoureurs()
    End Sub

    Private Sub FiltrerCoureurs()
        ' on vérifie qu'il y a bien au moins une course
        If ds.Tables("Courses").Rows.Count > 0 Then
            Dim strFilter As New StringBuilder
           ' on récupère la clef primaire de la course courante
            Dim pkCourse As String = CType(bsCourses.Current, DataRowView).Item("pkCourse").ToString

           ' on crée le filtre pour les coureurs
            For Each row As DataRow In ds.Tables("CoureursCourses").Rows
                If row("fkCourse").ToString = pkCourse Then
                    If strFilter.Length > 0 Then
                        strFilter.Append(" OR ")
                    End If
                    strFilter.Append("pkCoureur='" & row("fkCoureur").ToString & "'")
                End If
            Next

            If strFilter.Length > 0 Then
               ' filtrer les coureurs qui font partie de la course courante
                bsCoureurs.Filter = strFilter.ToString
            Else
                ' ne rien afficher si il n'y pas de coureurs dans la course
                bsCoureurs.Filter = "pkCoureur=''"
            End If
        End If
    End Sub

End Class